How much time left before dowload is complete?

[AdrianaBaron]

Hi im just wondering if there is any way I could figure out a guesstimate of how much time is left for the loader to complete loading... I would like to display this on screen like a count down. I'd greatly appreciate if someone knows thanks..

[GreenSock]

You could estimate the value using the loadTime and the progress. Kinda like:

 

var secondsLeft:Number = ((1 / myLoader.progress) - 1) * myLoader.loadTime;

 

This equation won't work if myLoader.progress is zero, though, so I'd recommend checking for that condition. You'd want to make sure that there's some progress made - the more progress, the more accurate the estimate will become.

[Nickbee]

I tried this code and my trace seems to be displaying the total time.... Am I doing something wrong?

 

function progressHandler(event:LoaderEvent):void 
{
if(queue.progress != 0)
{
	var secondsLeft:Number = (1 /queue.progress) * queue.loadTime;
	trace(int(secondsLeft));
}
}

trace result

4

5

5

5

5

5

5

5

5

5

5

 

THANKS!!!!!!!

[GreenSock]

Wups, sorry, I forgot to subtract 1:

 

var secondsLeft:Number = ((1 / myLoader.progress) - 1) * myLoader.loadTime;

[Nickbee]

Perfect!!!!! THANKS!!!!

[Nickbee]

in case anyone is interested this is how I displayed the time left in 00:00 format

 

function progressHandler(evt:LoaderEvent):void 
{
//percentage loaded
var pcent:Number = Math.ceil((evt.target.progress)*100);
preLoader_mc.loading_txt.text = "loading photos - " + pcent + "%";

//time left
if(myLoaderMax.progress != 0)
{
	var secondsLeft:uint = Math.ceil(((1 / myLoaderMax.progress) - 1) * myLoaderMax.loadTime);
	var minsLeft:uint = secondsLeft/60
	var mins:String;
	if (minsLeft < 10)
	{
		mins = "0" + minsLeft.toString();
	}else{
		mins = minsLeft.toString();
	}
	secondsLeft %= 60;
	var secs:String;
	if  (secondsLeft < 10)
	{
		secs = "0" + secondsLeft.toString();
	}else
	{
		secs = secondsLeft.toString();
	}
	preLoader_mc.time_txt.text = "time left - " + mins + ":" + secs;
}
}

 

see it in action here...

http://www.nickbee.com/LoaderMax

[GreenSock]

Very cool! Thanks for sharing.

 

By the way, you could probably simplify your code a bit, like this:

 

function progressHandler(evt:LoaderEvent):void {
  //percentage loaded
  var pcent:Number = int(evt.target.progress * 100);
  preLoader_mc.loading_txt.text = "loading photos - " + pcent + "%";

  //time left
  if (myLoaderMax.progress != 0) {
  var secondsLeft:Number = ((1 / myLoaderMax.progress) - 1) * myLoaderMax.loadTime;
  var mins:String = force2Digits(int(secondsLeft / 60));
  var secs:String = force2Digits(int(secondsLeft % 60));
  preLoader_mc.time_txt.text = "time left - " + mins + ":" + secs;
  }
}

function force2Digits(value:Number):String {
return (value }