TimelineLite Confusion [SOLVED]

[CantinaDan]

For some reason the code below is not functioning the way I assume it should. I'm sure the mistake is mine but I can't figure it out. I want the pic1_mc to disappear after the wipe1_mc does its thing. ie - first a 1.5 sec delay, then a .5 sec wipe, then the pic's alpha goes to zero. But when I test the movie the pic's alpha is zero right from the get go. Can't figure out why its not waiting until after that first append line of code. Any insight would be much appreciated!

 

var imageAni:TimelineLite = new TimelineLite();
	imageAni.append(TweenLite.to(wipe1_mc, .5, {y:324, delay:1.5}));
	imageAni.append(TweenLite.to(pic1_mc, 0, {alpha:0}));

[TronicVolta]

It's because TimelineLite by default sets align to "normal", not "sequence."

 

var imageAni:TimelineLite = new TimelineLite();
imageAni.appendMultiple([TweenLite.to(wipe1_mc, 0.5, {y:324, delay:1.5}),
 						     TweenLite.to(pic1_mc, 0, {alpha:0})], 0, "sequence");

[GreenSock]

Actually, it's because tweens with a duration of zero will render IMMEDIATELY (if you think about it, that kinda makes sense) but you can prevent that default behavior by passing immediateRender:false in the vars object.

 

var imageAni:TimelineLite = new TimelineLite();
imageAni.append(TweenLite.to(wipe1_mc, .5, {y:324, delay:1.5}));
imageAni.append(TweenLite.to(pic1_mc, 0, {alpha:0, immediateRender:false}));

 

The other option is to set the duration to a very small value like 0.001. But again, that's not necessary if you do immediateRender:false.

[CantinaDan]

Yes! Thank you, Jack. I was fiddling around with it and did find that if I put, like, .1 for the duration it solved the issue. Thanks for clueing me into the immediateRender:false option. I'll go with that!

[CantinaDan]

Just one more question related to this

 

I'd like to use the number that is calculated in my distance vars as a relative amount to move a movieClip in my TimelineLite. (I actually just recently realized that by putting a number in quotes it moves it that amount of pixels. Yeah, I'm slow.) If I have the actual number in quotes it functions properly. But if I put the var in quotes ("distanceV") it doesn't work properly. In this case it doesn't travel far enough? If I trace "distanceV" and "distanceH" I get the proper number in the output.

 

var distanceV:Number = stage.stageHeight + wipe1_mc.height;
var distanceH:Number = stage.stageWidth + wipe2_mc.width;

rockOn();

function rockOn():void
{
var imageAni:TimelineLite = new TimelineLite({onComplete:resetPositions});

	imageAni.append(TweenLite.to(wipe1_mc, .3, {y:"distanceV", delay:2, ease:Linear.easeNone}));
	imageAni.append(TweenLite.to(mask1_mc, .3, {y:"distanceV", ease:Linear.easeNone}), -.3);

	imageAni.append(TweenLite.to(wipe2_mc, .3, {x:"542", ease:Linear.easeNone}), 2);
	imageAni.append(TweenLite.to(mask2_mc, .3, {x:"542", ease:Linear.easeNone}), -.3);

	imageAni.append(TweenLite.to(wipe3_mc, .3, {y:"-674", ease:Linear.easeNone}), 2);
	imageAni.append(TweenLite.to(mask3_mc, .3, {y:"-674", ease:Linear.easeNone}), -.3);

	imageAni.append(TweenLite.to(wipe4_mc, .3, {x:"-542", ease:Linear.easeNone}), 2);
	imageAni.append(TweenLite.to(mask4_mc, .3, {x:"-542", ease:Linear.easeNone}), -.3);
}

[GreenSock]

Cast your variable as a String, like:

 

var myVariable:Number = 200;
TweenLite.to(mc, 2, {x:String(myVariable)});

[CantinaDan]

Thank you once again.